Jak udělat cestu složky univerzální?

Změnit nastavení Uložit řádek toto:

ActiveWorkbook.SaveAs "C:\Users\" & Environ("Username") & "\Desktop\Excel Assessment VBA\Excel Assessment VBA " & Format(Date, "dd-mmm-yyyy") & ".xlsm", FileFormat:=xlOpenXMLWorkbookMacroEnabled

Na Username systémová proměnná upraví v závislosti na účtu systému Windows, který je v provozu. Jen se ujistěte, že každý uživatel má tyto složky se nacházejí na jejich ploše příliš, nebo budete mít chybu. Jsem také odstraněny names ze složky jména jako předpokládám, že jste se snažili něco udělat s uživatelským jménem i tam. Můžete nastavit, že pro vaše potřeby.

Váš formát Data potřebná pro změnu příliš, jak to bylo včetně nelegálních znaků.

Také jste zapomněl zahrnout příponu souboru, tak jsem dodal, že stejně.

Tam je hodně děje s line, včetně hodně chyb, takže budete muset hrát s ním trochu, až se dostanete přesně to, co potřebujete. Možná budete chtít zjednodušit to trochu, až se dostanete na kloub, všechny ty věci.

Myslím, že budete muset přidat nějaké další kontroly

Skript očekává název tool-path-složka jako konstantní ToolFolder.

Plus druhá konstanta ToolBaseFolder to by mohlo být nastavena na mateřské-path `ToolFolder, např. síťová cesta. Pokud const je prázdný, uživatelé desktop bude použit.

Pokud je tato cesta ještě neexistuje, bude vytvořen.

Option Explicit

Private Const ToolBaseFolder As String = "" 'if ToolBaseFolder is an empty string desktop will be used instead
Private Const ToolFolder As String = "MyNameForToolFolder"


Public Sub testWbToToolFolder()
'this is just for testing
Dim wb As Workbook: Set wb = ActiveWorkbook
saveWbToToolFolder wb, "test.xlsx"
End Sub


Public Sub saveWbToToolFolder(wb As Workbook, filename As String)
'you don't need this sub - but have the same code line in your main routine
wb.SaveAs getToolFolder & filename
End Sub



Public Function getToolFolder() As String
'this returns the toolfolder e.g. C:\Users\xyz\Desktop\MyNameForToolFolder

Dim basepath As String
basepath = ToolBaseFolder & "\"

If existsFolder(basepath) = False Then
    If LenB(ToolBaseFolder) > 0 Then
        MsgBox ToolBaseFolder & " does not exist." & vbCrLf & _
            "File will be saved to " & ToolFolder & " on desktop ", vbExclamation
    End If
    basepath = getDesktopFolderOfUser
End If

Dim fullpath As String
fullpath = basepath & ToolFolder & "\"

If existsFolder(fullpath) = False Then
    makeFolder fullpath
End If

getToolFolder = fullpath

End Function


Private Function existsFolder(path As String) As Boolean
If Len(path) < 2 Then Exit Function 'can't be a valid folder
existsFolder = LenB(Dir(path, vbDirectory)) > 0
End Function

Private Function getDesktopFolderOfUser() As String
getDesktopFolderOfUser = CreateObject("WScript.Shell").SpecialFolders("Desktop") & "\"
End Function

Private Function makeFolder(path As String)
'https://stackoverflow.com/a/26934834/16578424 plus comment from rayzinnz
CreateObject("WScript.Shell").Run "cmd /c mkdir """ & path & """", 0, True
End Function